The Smilium language.

@core
@shell
 
number score = 42;        // whole or decimal
string name = "Marija";   // text
boolean happy = true;     // yes / no
 
// {curly} interpolation inside strings:
print("{name} scored {score}!");
print("double: {score * 2}");

@core
@shell
 
string name = ask("Your name? ");
number age = ask("How old are you? ");   // re-asks until it's a number
 
print("Hi {name}!");
print("Next year you will be {age + 1}.");

@core
@shell
 
number score = 87;
 
if(score over 50 and score isnt 100) {
    print("Nice score!", Colors.green);
}
else {
    print("Keep trying!");
}
 
// words and symbols are BOTH fine:
if(score >= 80 || score == 42) {
    print("Top tier");
}

@core
@shell
@system
 
number[] scores = [10, 25, 3];
scores.add(40);
 
print(scores);
print("count: {scores.length}, sum: {scores.sum()}");
print("best: {scores.max()}, avg: {scores.avg()}");
print(scores.contains(25));
 
scores.sort();
print(scores);

@core
@shell
 
string s = "Smilium is fun";
 
print(s.upper());
print(s.contains("fun"));
print(s.replace("fun", "POWER"));
print(s.split(" "));
print("len: {s.length}");

@core
@shell
 
func greet(string who) {
    print("Hello {who}!");
}
 
func double(number n) -> number {
    return (n * 2);
}
 
greet("Ana");
number d = double(21);
print(d);

@core
@shell
 
struct Player {
    string name;
    number score;
}
 
Player p = { name: "Ana", score: 10 };
print(p.name);
p.score = p.score + 5;
print(p);
 
// arrays of structs print as a TABLE
Player q = { name: "Bo", score: 25 };
Player[] team = [p, q];
print(team);

@core
@shell
 
enum Direction { up, down, left, right }
 
Direction way = Direction.up;
print(way);                    // enums print as their NAME
print("going {way}");
 
if(way == Direction.up) {
    print("north it is");
}
 
// when over an enum must cover EVERY value (or add a () catch-all)
when(way) {
    (Direction.up)     { print("N"); }
    (Direction.down)   { print("S"); }
    (Direction.left, Direction.right) { print("sideways"); }
}

@core
@shell
 
number score = 0;
 
// run a block whenever the value CHANGES
score.watch(old, new) {
    print("score: {old} -> {new}", Colors.magenta);
}
 
score = 10;
score = 10;      // no change -> nothing fires
score = 25;

@core
@shell
 
number age;
print(age is null);          // unset = null, never a sneaky 0
 
catch(string e) {
    print("the net caught: {e}");
}
 
number next = age + 1;       // using null = friendly stop -> the net
age = 9;
print(age + 1);              // now it's fine

@core
@shell
 
// one-line persistence for values
save("highscore", 420);
number best = load("highscore");
print(best);
 
// whole structs save as real JSON files
struct Player { string name; number score; }
Player p = { name: "Ana", score: 10 };
p.save("hero");                       // writes hero.json
Player back = Player.load("hero");
print(back.name);